메뉴 건너뛰기

Dev tips

Apache+Tomcat 윈도우 nginx 실행 배치 파일

taknim 2018.01.19 17:42 조회 수 : 473

D:\nginx-1.12.2 에 설치되어 있을때 아래와 같이 배치파일을 만들어서 실행하면 된다.

 

시작 배치 파일 (nginx_start.bat)

@ECHO OFF
D:
CD \nginx-1.12.2
nginx.exe -p D:\nginx-1.12.2 -c D:\nginx-1.12.2\conf\nginx.conf
종료 배치 파일 (nginx_stop.bat)

@ECHO OFF
D:
CD \nginx-1.12.2
nginx.exe -s stop

nginx.exe -s stop 으로 종료가 되지 않을 경우 tasskill 명령을 이용해서 강제 종료한다.

taskkill /f /im nginx.exe

 

실행할때 인자(args)를 받아서 처리하려면 아래와 같이 만들어준다.

배치 파일 (nginx.bat)

:Init
@ECHO OFF
D:
CD D:\nginx-1.12.2

 

:Condition
IF "%1" == "" GOTO Error
IF "%1" == "start" GOTO Start
IF "%1" == "stop" GOTO Stop
IF "%1" == "restart" GOTO Stop
IF "%1" == "reload" GOTO Reload
IF "%1" == "kill" GOTO Kill
GOTO Error

 

:Start
START /B nginx.exe -p D:\nginx-1.12.2 -c D:\nginx-1.12.2\conf\nginx.conf
ECHO nginx is started.
GOTO End

 

:Stop
nginx.exe -s stop
ECHO nginx is stopped.
IF "%1" == "restart" GOTO Start
GOTO End

 

:Reload
nginx.exe -s reload -p D:\nginx-1.12.2 -c D:\nginx-1.12.2\conf\nginx.conf
ECHO nginx is reloaded.
GOTO End

 

:Kill
TASKKILL /F /IM nginx.exe
ECHO nginx is killed.
GOTO End

 

:Error
ECHO Error! Invalid Parameter.

 

:End

실행하려면 배치파일이 있는 곳으로 이동(chdir)해서 아래와 같이 실행하면 된다.

nginx.bat start
nginx.bat stop
nginx.bat restart
nginx.bat reload
...

이 게시물을
목록
쓰기 태그